Musik / Soundwiedergabe mit dem ESP 8266

In Kombination mit dem MAX98357A Verstärkerchip (Datenblatt) kann der ESP 8266 in Kombination mit entsprechenden MP3 Software-Bibliotheken zur Musik / Soundwiedergabe z.B. per WLAN-Streaming genutzt werden.

Aufgrund des geringen Speichers klappt das nur bei niederigen Bit-Raten (z.B. 128 kBit/s) und einem stabilen WLAN gut, ansonsten kommt es zu Aussetzern. Alternativ kann in diesem Fall der ESP32 oder ein zusätzlicher SPI-Speicher (z.B. ) genutzt werden.

Hardware

• Wemos D1 Mini 8266 (*)
• MAX98357A Verstärker (*)

Schaltung

Code

// Based on https://github.com/earlephilhower/ESP8266Audio/blob/master/examples/StreamMP3FromHTTP/StreamMP3FromHTTP.ino

#include <ESP8266WiFi.h>
#include "AudioOutputI2S.h"
#include "AudioFileSourceHTTPStream.h"
#include "AudioFileSourceBuffer.h"
#include "AudioGeneratorMP3.h"

const char* ssid = "example";
const char* password =  "password";

AudioGeneratorMP3 *mp3;
AudioFileSourceHTTPStream *file;
AudioFileSourceBuffer *buff;
AudioOutputI2S *out;

// Called when there's a warning or error (like a buffer underflow or decode hiccup)
void StatusCallback(void *cbData, int code, const char *string)
{
  const char *ptr = reinterpret_cast<const char *>(cbData);
  // Note that the string may be in PROGMEM, so copy it to RAM for printf
  char s1[64];
  strncpy_P(s1, string, sizeof(s1));
  s1[sizeof(s1)-1]=0;
  Serial.printf("STATUS(%s) '%d' = '%s'\n", ptr, code, s1);
  Serial.flush();
}

float gain = 0.1;

void setup() {
  Serial.begin(115200);
  delay(1000);
  Serial.println("Connecting to WiFi");
  WiFi.begin(ssid, password);
    
  // Try forever
  while (WiFi.status() != WL_CONNECTED) {
    Serial.println("...Connecting to WiFi");
    delay(1000);
  }
  Serial.println("Connected");

  audioLogger = &Serial;
  file = new AudioFileSourceHTTPStream("http://example.com/sample.mp3");
  buff = new AudioFileSourceBuffer(file, 10000);
  buff->RegisterStatusCB(StatusCallback, (void*)"buffer");
  out = new AudioOutputI2S();
  out->SetGain(gain);
  mp3 = new AudioGeneratorMP3();
  mp3->RegisterStatusCB(StatusCallback, (void*)"mp3");
  mp3->begin(buff, out);
}

void loop()
{
  static int lastms = 0;

  if (mp3->isRunning()) {
    if (millis()-lastms > 1000) {
      lastms = millis();
      Serial.printf("Running for %d ms... gain %f\n", lastms, gain);
      Serial.flush();
    }
    if (!mp3->loop()) mp3->stop();
  } else {
    Serial.printf("MP3 done\n");
    delay(1000);
  }
}